vba code for accessible books

[egyblind]

hello sirs

i'm new member here, wish you help me
i'm visually impaired, so would like to modify some files to be more accessible for me and others,


first thing, need to convert all footnotes and endnotes in a word file into normal text only start by FN for footnote and EN for endnote.
also convert its reference number inside text to normal (#)
thanks very much for your support

[Turtle91]

Not sure exactly what you are looking for.
What do you mean by converting FN/EN to "normal" text or normal number? How is it formatted now and what is your definition of normal?
What software are you using? What format are your books currently?

Welcome to MR!

[Doitsu]

Originally Posted by Turtle91

Not sure exactly what you are looking for.
What do you mean by converting FN/EN to "normal" text or normal number? How is it formatted now and what is your definition of normal?

@Turtle91: The OP most like wants to directly embed footnote and endnote definitions in the body text so that they're automatically read when s/he uses VoiceOver (TTS).

E.g. Instead of:

This is a footnote[1] in the body text.
[1] an additional piece of information printed at the bottom of a page

s/he probably wants:

This is a footnote (footnote 1: an additional piece of information printed at the bottom of a page) in the body text.

I'm pretty sure that this can be done with VBA, but I haven't used MS Word macros in ages. Also since macOS has TTS features built into OS there might be a non-standard iBooks epub3 extension that'll automatically retrieve footnote definitions or dedicated iOS apps for visually impaired readers that'll do this automatically.

[Toxaris]

This can be done with VBA, but I haven't worked with VBA for ages.

[egyblind]

hello

yes i want to embed footnote and endnote definitions in the body text and put "fn" / "en" before the text to be known its footnote / endnote.

am using microsoftword file.doc
thanks

[Doitsu]

@egyblind:

It might be possible to create a Calibre plugin that'll embed footnote/endnote definitions in the body text. Maybe you could ask about it in the Calibre Plugin Ideas thread?

I've got a couple of additional questions:

1. Have you already created a couple of MS Word documents with footnote references in them that you want to convert or do you create these documents from scratch as needed?

2. What tool do you use to convert MS Word documents to epub books?

3. Did you investigate whether iBooks Author has any accessibility features that'll mark up footnote/endnote definitions so that they're automatically read by VoiceOver?

[egyblind]

hello Doitsu
i need to do this in word files .doc and .docx
and will read them on windows pc on ms-word

the documents i've contains footnotes and endnotes + other objects but i not like to write long topic for this asked about footnotes and endnootes only.
all i need vba macro for word.
thanks

Originally Posted by Doitsu

@egyblind:

It might be possible to create a Calibre plugin that'll embed footnote/endnote definitions in the body text. Maybe you could ask about it in the Calibre Plugin Ideas thread?

I've got a couple of additional questions:

1. Have you already created a couple of MS Word documents with footnote references in them that you want to convert or do you create these documents from scratch as needed?

2. What tool do you use to convert MS Word documents to epub books?

3. Did you investigate whether iBooks Author has any accessibility features that'll mark up footnote/endnote definitions so that they're automatically read by VoiceOver?

[elibrarian]

Originally Posted by egyblind

hello

yes i want to embed footnote and endnote definitions in the body text and put "fn" / "en" before the text to be known its footnote / endnote.

This should do it:

'---------------------------------------------------------------------------------------
' Method : Notes2Inline
' Author : Kim
' Date   : 11-02-2017
' Purpose: Convert footnotes/endnotes to inline text
'---------------------------------------------------------------------------------------
Sub Notes2Inline()

    Dim oFNs As Footnotes
    Dim oFN As Footnote
    Dim oENs As Endnotes
    Dim oEN As Endnote
    Dim oRng As Range
    Dim strFNText As String
    Dim strENText As String
    Dim lngIndex As Long 'variable for note number. If not wanted, remove _
    " & lngIndex & " (including qoutation marks) from the With oRng.Text lines below
     
    Set oFNs = Word.ActiveDocument.Footnotes
    For Each oFN In oFNs
        strFNText = oFN.Range.Text
        lngIndex = lngIndex + 1
        Set oRng = ActiveDocument.Range
        With oRng.Find
            .Text = "^f" ' Looks for all footnotes
            .Forward = True
            .Wrap = wdFindStop
            If .Execute Then
                oFN.Delete
                With oRng
                    .Text = " [Footnote " & lngIndex & ": " & strFNText & "]"
                    .Font.Color = wdColorDarkBlue 'Color text taken from endnotes blue
                End With
            End If
        End With
         'Uncomment to disable undo to save memory on very large documents.
         'ActiveDocument.UndoClear
    Next

    Set oENs = Word.ActiveDocument.Endnotes
    For Each oEN In oENs
        strENText = oEN.Range.Text
        lngIndex = lngIndex + 1
        Set oRng = ActiveDocument.Range
        With oRng.Find
            .Text = "^e" ' Looks for all endnotes
            .Forward = True
            .Wrap = wdFindStop
            If .Execute Then
                oEN.Delete
                With oRng
                    .Text = " [Endnote " & lngIndex & ": " & strENText & "]"
                    .Font.Color = wdColorDarkRed 'Color text taken from endnotes red
                End With
            End If
        End With
         'Uncomment next line to disable undo to save memory on very large documents.
         'ActiveDocument.UndoClear
    Next

End Sub

To be honest, I didn't forge the code myself, found it by a google search for "vba footnote to text" and modified it a little to cater for endnotes as well

Regards,

Kim