calibre bat file windows 7 64bit

[Dopedangel]

I am using bat files and dropbox to open my calibre library on different computers. earlier I was using a xp machine
just bought a new windows 7 64bit now when I try that batch file hundreds of dos box start appearing and calibre does not open. Any one has any Idea what I should change in the bat file to make it work

[banjomike]

Originally Posted by Dopedangel

Any one has any Idea what I should change in the bat file to make it work

A good start would be to post your batchfile here so we can see what you have.

[Dopedangel]

here is the original bat file I am using and was working fine on my windows machine

@echo OFF
REM			CalibreRun.bat
REM			~~~~~~~~~~~~~~
REM Batch File to start a Calibre configuration on Windows
REM giving explicit control of the location of:
REM  - Calibe Program Files
REM  - Calibre Library Files
REM  - Calibre Config Files
REM  - Calibre Metadata database
REM  - Calibre Source files
REM By setting the paths correctly it can be used to run:
REM  - A "portable calibre" off a USB stick.
REM  - A network installation with local metadata database
REM    (for performance) and books stored on a network share 
REM
REM If trying to run off a USB stick then the following 
REM folder structure is recommended:
REM  - Calibre2			Location of program files
REM  - CalibreConfig		Location of Configuration files
REM  - CalibreLibrary		Location of Books and metadata


REM -------------------------------------
REM Set up Calibre Config folder
REM -------------------------------------

If EXIST CalibreConfig SET CALIBRE_CONFIG_DIRECTORY=%cd%\CalibreConfig


REM --------------------------------------------------------------
REM Specify Location of ebooks
REM
REM Location where Book files are located
REM Either set explicit path, or if running from a USB stick
REM a relative path can be used to avoid need to know the
REM drive letter of the USB stick.

REM Comment out any of the following that are not to be used
REM --------------------------------------------------------------

SET CALIBRE_LIBRARY_DIRECTORY=%cd%\Library




REM --------------------------------------------------------------
REM Specify Location of metadata database  (optional)
REM
REM Location where the metadata.db file is located.  If not set
REM the same location as Books files will be assumed.  This.
REM options is used to get better performance when the Library is
REM on a (slow) network drive.  Putting the metadata.db file 
REM locally gives a big performance improvement.
REM --------------------------------------------------------------





REM --------------------------------------------------------------
REM Specify Location of calibre binaries (optinal)
REM
REM To avoid needing Calibre to be set in the search path, ensure
REM that Calibre Program Files is current directory when starting.
REM The following test falls back to using search path .
REM This folder can be populated by cpying the Calibre2 folder from
REM an existing isntallation or by isntalling direct to here.
REM --------------------------------------------------------------

C:
CD \Program Files\Calibre2



REM --------------------------------------------
REM Display settings that will be used
REM --------------------------------------------

echo PROGRAMS=%cd%
echo SOURCE=%CALIBRE_DEVELOP_FROM%
echo CONFIG=%CALIBRE_CONFIG_DIRECTORY%
echo LIBRARY=%CALIBRE_LIBRARY_DIRECTORY%
echo DATABASE=%CALIBRE_OVERRIDE_DATABASE_PATH%

REM  The following gives a chance to check the settings before
REM  starting Calibre.  It can be commented out if not wanted.



REM --------------------------------------------------------
REM Start up the calibre program.
REM
REM The use of 'belownormal' priority helps keep the system
REM responsive while Calibre is running.  Within Calibre itself
REM the backgound processes should be set to run with 'low' priority.

REM Using the START command starts up Calibre in a separate process.
REM If used without /WAIT opotion launches Calibre and contines batch file.
REM Use with /WAIT to wait until Calibre completes to run a task on exit
REM --------------------------------------------------------

echo "Starting up Calibre"
START /belownormal Calibre --with-library "%CALIBRE_LIBRARY_DIRECTORY%"

[CRussel]

Without digging at all deeply into your script, I spotted one problem right away:

C:
CD \Program Files\Calibre2

Won't work. Calibre is a 32-bit program, so will be in %ProgramFiles(x86)%.

[itimpi]

There should be a more recent (and improved) version of that Batch file in the resources sub-folder in the Calibre install folder.

You would need to check through it that the paths are correct for your setup.

Note that as long as Calibre is on the system search path it will be found regardless of the current folder at the time you run the batch file. If it is not on the system search path then you want to make sure that the batch file sets the correct location.

However I am not sure why you should ever get the symptom you mentioned of lots of DOS boxes opening up when it does not work!

[banjomike]

Originally Posted by itimpi

However I am not sure why you should ever get the symptom you mentioned of lots of DOS boxes opening up when it does not work!

I think you would get that if the batchfile was called Calibre and was in the current folder when "START /belownormal Calibre" was reached. If the batchfile cannot change to the Calibre folder (maybe because of CRussel's suggestion) then it would rerun itself again and again probably in a separate ntvdm (or whatever the 64bit version is called). I'm not certain you would get hundreds, I would expect Windows to explode before it got to that number.

[Dopedangel]

Well I was not able to make it work without hard coding the exact directories for the config and library. And reinstalling calibre in C:\caibre2
Currently I am running the bat file from the calibre directory what should I write if I want to place the bat file somewhere else.

[itimpi]

As long as all the paths in the batch file are set correctly for your system, then the location of the batch file should be irelevant.

The batch file is aimed it making it easy to run from a USB stick, but if you are not doing that and are therefore not using the recommended folder structure (so that relative paths can be used) then simply set the paths to be absolute ones.

[Dopedangel]

Ok I got it working by installing calibre in C:\Calibre2 on both computers
and removing the If statement for the Binary locations and just using

CD C:\Calibre2
ECHO PROGRAM FILES: %cd%